Morgen!

Ich da ein kleines Problem und hoffe iihr könnt mir dabei helfen....

Ich würde mir gerne eine "Profilsäuberungsbatch" Datei schreiben, da unsere Profile nur 50MB groß sein dürfen und das sehr schnell der Fall ist :floet:

Die Datei sollte gar net so viel können, nur ein paar Ordner im Profil, bzw. deren Inhalt löschen(ausser die index.dat bei den Cookies) und mich am ende fragen ob es wirklich gelöscht werden soll. Leider weiß ich überhaupt net wie sowas funktioniert :confused:

Würde mich freuen wenn ihr mir helfen könntet.

Gruß Piccolo2045

Ich habe mal gerade nen kleinen Batch für dich geschrieben, vielleicht hilft er dir , Benutzung auf eigene Gefahr:

@echo off

SET QUELLE1=C:\Dokumente und Einstellungen

SET QUELLE2=Lokale Einstellungen\Temporary Internet Files\Content.IE5

SET QUELLE3=Lokale Einstellungen\Verlauf

SET QUELLE4=Lokale Einstellungen\Temp

SET QUELLE5=Cookies

echo Temporaere Internetdateien loeschen?

SET Choice=

SET /P Choice=[J]a oder [N]ein

IF /I '%Choice%'=='J' GOTO deltempinet

IF /I '%Choice%'=='N' GOTO nodeltempinet

goto end

:deltempinet

echo.

echo Loesche Temporaere Internet Dateien..

FOR /D %%X IN ("%QUELLE1%\*") DO FOR /D %%Y IN ("%%X\%QUELLE2%\*.*") DO RMDIR /S /Q "%%Y"

:nodeltempinet

echo.

echo Verlauf loeschen?

SET Choice=

SET /P Choice=[J]a oder [N]ein

IF /I '%Choice%'=='J' GOTO delverlauf

IF /I '%Choice%'=='N' GOTO nodelverlauf

goto end

:delverlauf

echo.

echo Loesche Verlaufs Dateien..

FOR /D %%X IN ("%QUELLE1%\*") DO FOR /D %%Y IN ("%%X\%QUELLE3%\*.*") DO RMDIR /S /Q "%%Y"

FOR /D %%X IN ("%QUELLE1%\*") DO FOR %%Y IN ("%%X\%QUELLE3%\*.*") DO DEL /F /S /Q "%%Y"

:nodelverlauf

echo.

echo Tempdateien loeschen?

SET Choice=

SET /P Choice=[J]a oder [N]ein

IF /I '%Choice%'=='J' GOTO deltemp

IF /I '%Choice%'=='N' GOTO nodeltemp

goto end

:deltemp

echo.

echo Loesche Tempdateien..

FOR /D %%X IN ("%QUELLE1%\*") DO FOR /D %%Y IN ("%%X\%QUELLE4%\*.*") DO RMDIR /S /Q "%%Y"

FOR /D %%X IN ("%QUELLE1%\*") DO FOR %%Y IN ("%%X\%QUELLE4%\*.*") DO DEL /F /S /Q "%%Y"

:nodeltemp

echo.

echo Cookies loeschen?

SET Choice=

SET /P Choice=[J]a oder [N]ein

IF /I '%Choice%'=='J' GOTO delcookies

IF /I '%Choice%'=='N' GOTO end

goto end

:delcookies

echo.

echo Loesche Cookies

FOR /D %%X IN ("%QUELLE1%\*") DO FOR %%Y IN ("%%X\%QUELLE5%\*.txt") DO DEL /F /S /Q "%%Y"

:end

pause

WOW!!!! Das ist ja SUPER!

Vielen Dank erstmal, ich denke das wird mir auf jeden Fall weiter helfen :uli